Herdabschaltung (Totmannschaltung) für Vergessliche

    Diese Seite verwendet Cookies. Durch die Nutzung unserer Seite erklären Sie sich damit einverstanden, dass wir Cookies setzen. Weitere Informationen

    Aufgrund technischer Veränderungen ist der Mailverkehr innerhalb des Forums (Private Nachrichten) nur noch eingeschränkt möglich. Die Einschränkung ist notwendig, um zusätzliche Betriebskosten für das Forum zu vermeiden. Näheres zu den Hintergründen im Thread "Aktuelles zum Forum".Wir bitten um Verständnis.

    Hinweis kann nach Kenntnisnahme deaktiviert werden!

    • Herdabschaltung (Totmannschaltung) für Vergessliche

      Nachdem meine Schwiegermutter immer vergesslicher wird und auch schon mal den Herd vergessen hat, hab' ich mich nach Herdsicherungen umgesehen:
      amazon.de/Gorilla%C2%AE-stove-…-1&keywords=gorilla+stove zeigt ein Gerätchen, was nur piepst und weiter unten werden abschaltende Geräte aufgelistet. Preise ab 129€ aufwärts.
      Gut, wenn ich die Vorgaben hab', kann ich das auch selber machen und hab' am Wochenende mal programmiert, gefräst und gelötet. Herausgekommen ist eine Totmannschaltung mit Restzeitanzeige und eine akustische 'bald ist der Strom weg'-Anzeige. Durch jumper kann eine Zeitvorwahl zwischen 10 und 25 Minuten (im Programm änderbar) eingestellt werden. Durch Drücken des Starttasters wird diese Zeit übernommen, am display in Minuten angezeigt und der Schütz für die Herdstromversorgung wird eingeschaltet. Es kann gekocht werden. 3 Minuten vor ablauf der Zeit fängt die Klingel zart das glöckeln an, ein Kling, 3 Sekunden Pause. (Das geht mit Wechselstromklingeln aus dem Baumarkt gut.) Wird die Starttaste gedrückt, wird das Klingeln gestoppt und die Zeitvorgabe läuft neu los. Drückt man die Stopptaste wird das Klingeln gestoppt aber der Schütz fällt auch ab und der Herd ist stromlos. Reagiert man nicht auf das Klingeln, wird dieses in der vorletzten Minute heftiger und in der letzten Minute penetrant. Reagiert man immer noch nicht, wird nach Ablauf der Zeit Klingeln und Herdstrom abgeschaltet, der mögliche Schaden wird dadurch in Grenzen gehalten.
      Hier mal Programm und Bilder der Steuerung, der Hochstromteil (Schütz) besteht aus SSRs in einem separaten Gehäuse. Das Gehäuse der Steuerung wird aus einem Multiplexbrettchen herausgefräst (fehlt auch noch).

      BASCOM-Quellcode

      1. 'Herdabschaltung Totmannschaltung
      2. 'Anzeige mit Multiplex
      3. $regfile = "m168pdef.dat"
      4. $crystal = 8000000
      5. $hwstack = 64
      6. $swstack=32
      7. $framesize = 30
      8. 'ports
      9. Relais Alias Portc.2 'steuert den Schütz für die Herdstromversorgung
      10. Config Relais = Output
      11. Klingel Alias Portc.3 'Anschluss für Wechselstromklingel, ein Impuls gibt einen Glockenschlag
      12. Config Klingel = Output
      13. Set_2 Alias Pinc.4
      14. Config Set_2 = Input 'preset für die Laufzeit
      15. Portc.4 = 1
      16. Set_1 Alias Pinc.5
      17. Config Set_1 = Input 'preset für die Laufzeit
      18. Portc.5 = 1
      19. T_start Alias Pinc.0 'Starttasten gibt Strom für Herd frei gemäß preset-Zeit
      20. Config T_start = Input
      21. Portc.0 = 1
      22. T_stop Alias Pinc.1 'Stopptaste, stoppt Klingeln, schaltet Herdstrom ab
      23. Config T_stop = Input
      24. Portc.1 = 1
      25. Segmente Alias Portd
      26. Config Segmente = Output 'Kathoden 7-Segmentanzeigen
      27. Z_enable Alias Portb.0 'Anode Zehnerstelle 7-Segmentanzeige
      28. Config Z_enable = Output
      29. E_enable Alias Portb.1 'Anode Einerstelle 7-Segmentanzeige
      30. Config E_enable = Output
      31. Const Timer2reload = 39 '5mSec
      32. Config Timer2 = Timer , Prescale = 1024
      33. load timer2 , Timer2Reload
      34. on ovf2 Timer2_isr
      35. enable ovf2
      36. Start Timer2
      37. Enable Interrupts
      38. 'Variablen
      39. Dim Laufzeit As Word 'Laufzeit in Sekunden
      40. Dim Aktiv As Bit '=1 wenn Herd bedienbar
      41. Dim Alarm As Bit '=1 wenn geklingelt wird
      42. Dim Anzeige_enable As Bit '=1 wenn die Anzeige was zeigen soll
      43. Dim Alarm_frequenz As Byte , Alarm_frequenz1 As Byte 'Anzahl Sekunden pro Glockenschlag
      44. Dim Alarm_puls As Word , Alarm_puls1 As Word 'Pulslänge für Glockenschlag in 5mSec
      45. Dim Minuten As Word , E As Word , Z As Word , Dp As Byte 'für Anzeige
      46. Dim Einer As Byte , Zehner As Byte , Stelle As Bit
      47. Dim Flag As Bit
      48. Dim 1_sec As Byte
      49. 'Voreinstellungen
      50. Aktiv = 0
      51. Alarm_puls = 16
      52. Config Debounce = 50
      53. Do
      54. Flag = 0
      55. Bitwait Flag , Set
      56. Debounce T_start , 0 , Starten , Sub
      57. Debounce T_stop , 0 , Stoppen , Sub
      58. If Aktiv = 1 Then
      59. Gosub Anzeige 'Restzeit in Minuten ausgeben
      60. Select Case Laufzeit
      61. Case Is > 180 : Alarm = 0
      62. Case 121 To 180 : Alarm_frequenz = 3 : Alarm = 1 'Glockenschlag alle 3 Sekunden
      63. Case 61 To 120 : Alarm_frequenz = 2 : Alarm = 1 'Glockenschlag alle 2 Sekunden
      64. Case 1 To 60 : Alarm_frequenz = 1 : Alarm = 1 'Glockenschlag alle 1 Sekunde
      65. Case 0 : Gosub Stoppen
      66. End Select
      67. Else
      68. Gosub Stoppen
      69. End If
      70. Loop
      71. Anzeige:
      72. Minuten = Laufzeit / 60
      73. E = Minuten Mod 10 'Zahl in einzelne Stellen zerpflücken
      74. Z = Minuten / 10
      75. Einer = Lookup(e , Zeichentabelle )
      76. If Dp.0 = 1 Then Einer.7 = 1 Else Einer.7 = 0
      77. If Z = 0 Then Z = 10 'Zehner-Nuller unterdrücken
      78. Zehner = Lookup(z , Zeichentabelle )
      79. Return
      80. Starten:
      81. Disable Interrupts
      82. Laufzeit = 599 '10 Minuten, wenn kein Jumper gesteckt
      83. If Set_1 = 0 Then Laufzeit = 899 '15 Minuten, wenn nur Jumper 1 gesteckt
      84. If Set_2 = 0 Then Laufzeit = 1199 '20 Minuten, wenn nur Jumper 2 gesteckt
      85. If Set_1 = 0 And Set_2 = 0 Then Laufzeit = 1499 '25 Minuten, wenn beide Jumper gesteckt
      86. Aktiv = 1
      87. Alarm = 0
      88. Relais = 1 'Herdstrom einschalten
      89. Anzeige_enable = 1 'Anzeige einschalten
      90. Enable Interrupts
      91. Return
      92. Stoppen:
      93. Aktiv = 0
      94. Alarm = 0
      95. Relais = 0 'Herdstrom abschalten
      96. Anzeige_enable = 0 'Anzeige ausschalten
      97. Return
      98. Timer2_isr:
      99. Load Timer2 , Timer2reload 'timer2 5mSec
      100. Toggle Stelle
      101. If Stelle = 0 Then 'Zehnerstelle anzeigen
      102. E_enable = 0 'Einerstelle ausschalten
      103. Segmente = Zehner
      104. Z_enable = Anzeige_enable 'Zehnerstelle anschalten
      105. Else
      106. Z_enable = 0 'Zehnerstelle ausschalten
      107. Segmente = Einer
      108. E_enable = Anzeige_enable 'Einerstelle anschalten
      109. End If
      110. If Alarm_puls1 > 0 Then Decr Alarm_puls1 'Pulszeit läuft ab
      111. If Alarm_puls1 = 0 Then
      112. Klingel = 0 'Klingel stromlos
      113. End If
      114. If 1_sec > 0 Then Decr 1_sec
      115. If 1_sec = 0 Then '1 Sekunde vergangen
      116. 1_sec = 200
      117. Toggle Dp.0 'Dezimalpunkt blinkt
      118. If Laufzeit > 0 Then Decr Laufzeit 'Laufzeit sekundenweise runter zählen
      119. If Alarm = 1 Then
      120. If Alarm_frequenz1 > 0 Then Decr Alarm_frequenz1
      121. If Alarm_frequenz1 = 0 Then
      122. Klingel = 1 'Strom auf Klingel
      123. Alarm_puls1 = Alarm_puls 'Pulslänge einstellen
      124. Alarm_frequenz1 = Alarm_frequenz 'Neustart der Alarm_frequenz
      125. Else
      126. Klingel = 0
      127. End If
      128. End If
      129. End If
      130. Flag = 1
      131. Return
      132. Zeichentabelle:
      133. 'Segment dp,G,F,E,D,C,B,A invertiert
      134. Data &B1100_0000 '0
      135. Data &B1111_1001 '1
      136. Data &B1010_0100 '2
      137. Data &B1011_0000 '3
      138. Data &B1001_1001 '4
      139. Data &B1001_0010 '5
      140. Data &B1000_0010 '6
      141. Data &B1111_1000 '7
      142. Data &B1000_0000 '8
      143. Data &B1001_0000 '9
      144. Data &B1111_1111 'nix
      Alles anzeigen
      Herdabschaltung-V0.2.pngHerdabschaltung-V0.2-board.pngPlatine-Unterseite.jpgPlatine-bestückt.jpgDraufsicht.jpg
      Start- und Stopptaster sind Klingeltaster, die schön zu beschriften sind. Die Platine ist 100x114mm (BxH) groß.
      Ok, der atmega168 ist überdimensioniert, aber ich hab' mir eingebildet, ich muss das in SMD machen und da war der der kleinste vorrätige.
      (Eagle-Dateien auf Anfrage)
      Raum für Notizen

      -----------------------------------------------------------------------------------------------------

      -----------------------------------------------------------------------------------------------------

      Dieser Beitrag wurde bereits 2 mal editiert, zuletzt von tschoeatsch ()

    • Riedleweg schrieb:

      Gut gelöst.

      Über kurz oder lang muß ich mir bei meiner Mutter ähnliches überlegen.

      Du machst den ganzen Herd stromlos?

      Wiedereinschalten der Herdversorgung durch den Starttaster?
      Genau. Das ist ein ganz einfacher Herd, keine Schaltuhr, nur 4 Platten und die Röhre. Die SSR sind einfach zwischen Wandanschluss und Herdanschluss.
      Raum für Notizen

      -----------------------------------------------------------------------------------------------------

      -----------------------------------------------------------------------------------------------------
    • Naja, Rauchmelder sollen in der Küche oft Fehlalarm geben, zumal auch kein Dunstabzug vorhanden ist. Bei 'hightech-Herden' wird's komplizierter, da hab' ich ja Glück.
      Raum für Notizen

      -----------------------------------------------------------------------------------------------------

      -----------------------------------------------------------------------------------------------------
    • Ich kenn das von Bekannten...Der Rauchmelder geht z.b. beim Reiskochen nach ca 2H an X/ . Mit 600er Schleifpapier aufm Akkuschrauber wird der Edelstahltopf wieder brauchbar. Die Elektrikerlösung war dann der Bewegungsmelder der nach maximaler Zeit (15min) den schütz vorm Herd abgeschaltet hat.

      Ist aber 20 Jahre her und war die Lösung die der Elektriker für die Oma selber hinbekommen hatte. Die Bascom Variante ist da natürlich wesentlich luxuriöser a_42_02cc30b2
      Ich such sowas als Fertigprodukt, die Fussheizmattem unserer Bürodamen laufen nämlich 24/7 durch weil sie nie abgeschaltet werden. Da schnauft die Klimaanlage im Sommer, aber die Heizmatte läuft weiter volle pulle unterm Tisch.

      Tobias
    • HansHans schrieb:

      Also nach dem Totmann aus: erst wieder Uhr einstellen ….
      Früher war alles besser. Da haben wir die IBM Schreibmaschine (gefühlt 100 Tasten) per 100 Elektromagneten zum Drucker gewandelt.
      Sollte doch heutzutage ein Leichtes sein, die zwei oder drei Herd-Uhren-Tasten per Arduino, Wifi-Shield, Elektromagneten und Schrittmotoren wieder neu zu stellen, damit die Schwiegermutter sofort wieder kochen kann...
      Tschoeatsch, wie wär's noch damit?
      Gruß, elektron
    • Kalle_BMW schrieb:

      Info: im Schaltplan 20 MHz, im Code 8 MHz
      Stimmt, ich hab' das Quarz nicht bestückt, Schaltbild = optional, code = real. (Ich muss auch noch den 5mSec interrupt auf echte 5 mSec bringen)

      elektron schrieb:

      Sollte doch heutzutage ein Leichtes sein, die zwei oder drei Herd-Uhren-Tasten per Arduino, Wifi-Shield, Elektromagneten und Schrittmotoren wieder neu zu stellen, damit die Schwiegermutter sofort wieder kochen kann...
      Tschoeatsch, wie wär's noch damit?
      Zum Glück nicht meine Baustelle, Schwiegermutters Herd ist ohne Intelligenz a_30_7dc14a07
      Raum für Notizen

      -----------------------------------------------------------------------------------------------------

      -----------------------------------------------------------------------------------------------------
    • Jetzt hab' ich's kapiert!
      Ich hab' keine Erfahrungen mit Rauchmelder in der Küche, drum ist es für mich schwierig den richtigen Platz dafür zu finden. Beim normalen Kochen entsteht ja auch Dampf und Fettdunst, und dann den Unterschied zwischen Fettbrand und harte Eier zu finden, hm. Außerdem, was macht die Schwiegermutter, wenn es ein Fehlalarm wäre und der Rauchmelder hat den Herd abgeschaltet? Richtig, es wird telefoniert und wer muss springen? a_58_b54cfdb4
      Also simple Technik bei einem simplen Herd.
      Raum für Notizen

      -----------------------------------------------------------------------------------------------------

      -----------------------------------------------------------------------------------------------------
    • Klar den will keiner aber Fehlalarme will auch keiner :)

      Übrigens mal noch was zu modernen Herden
      Die ließen sich sogar einfacher abschalten da ja alles schon elektronisch gesteuert wird.
      Bei meinem Herd wird alles über kleine Relais geschaltet und die lassen sich einfacher ansteuern.
      Und der Backofen hat bei mir auch schon eine Schutzabschaltung drin.
      Eine Lösung habe ich nicht, aber mir gefällt Ihr Problem.
    • Dann wäre das was für die Herdhersteller, als ansteckbares Zubehör. Ein Markt hierfür ist sicherlich vorhanden, die bisher erhältlichen Warner und Stromtrenner sind ja nur Notlösungen.
      Raum für Notizen

      -----------------------------------------------------------------------------------------------------

      -----------------------------------------------------------------------------------------------------
    • Fast fertig, fehlt noch der Kasten mit den SSRs. Das Bedienteil hat ein Holzgehäuse bekommen und wird mit den 4 Magneten an der Kühlschrankseite (der steht auf der Spüli neben dem Herd) 'angepappt'.
      Ansicht.jpgGehäuseinnenansicht.jpg
      Raum für Notizen

      -----------------------------------------------------------------------------------------------------

      -----------------------------------------------------------------------------------------------------
    • djmsc schrieb:

      Könntest du die SSR's nicht direkt im Herd einbauen?
      Könnte man schon, wäre auch sicher eleganter. Aber mit einem extra Kästchen kann ich alles zu Hause vorbereiten und hab' nur 'Wanddose auf und zu' und 'Herdanschluss auf und zu'. Da ist nix unvorhergesehenes.
      Raum für Notizen

      -----------------------------------------------------------------------------------------------------

      -----------------------------------------------------------------------------------------------------